View source for Testwiki:Request a query/Archive/2017/02

{{Archive|category=Request a query archive}}

== Wikisites without that label ==

Is it possible to create a list with all items that have a page in a specific language, but not a label in that language on Wikidata? Like {{Q|16992050}}, it has a page in nl, but no label in nl. [[User:QZanden|Q.Zanden]] <small>[[User talk:QZanden|questions?]]</small> 22:18, 31 January 2017 (UTC)
:This is an example for {{Q|Q3026819}}:
:{{SPARQL|query=SELECT ?item WHERE {
  ?article schema:about ?item ;
  schema:isPartOf <https://rm.wikipedia.org/> .
  OPTIONAL { ?item rdfs:label ?title . FILTER(lang(?title)="rm") } .
  FILTER(!BOUND(?title))
}
}} For bigger projects like nlwiki the query times out. --[[User:Pasleim|Pasleim]] ([[User talk:Pasleim|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 14:26, 1 February 2017 (UTC)
@Pasleim, Thank you! Does the query also time out when you set a limit? [[User:QZanden|Q.Zanden]] <small>[[User talk:QZanden|questions?]]</small> 14:33, 1 February 2017 (UTC)
== Females with male given names ==

Might I request a report showing items with an en.wiki article, in which the gender is female but the given name is a male given name
*{{P|21}} = {{Q|6581072}}, value for {{P|735}} is an instance of {{Q|12308941}}. thanks --[[User:Tagishsimon|Tagishsimon]] ([[User talk:Tagishsimon|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 00:49, 1 February 2017 (UTC)
{{SPARQL|query=SELECT ?item ?itemLabel ?name ?nameLabel
WHERE
{
	?article 	schema:about ?item ;
			schema:isPartOf <https://en.wikipedia.org/> .
  ?item wdt:P21 wd:Q6581072 .
  ?item wdt:P735 ?name .
  ?name wdt:P31 wd:Q12308941
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en" }
}
LIMIT 200
}}--[[User:ԱշոտՏՆՂ|ԱշոտՏՆՂ]] ([[User talk:ԱշոտՏՆՂ|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 10:49, 1 February 2017 (UTC)
:Maybe this can be useful as well:
:{{SPARQL|query=#defaultView:ImageGrid
SELECT ?item ?itemLabel ?name ?nameLabel ?image
WHERE
{
	?article 	schema:about ?item ;
			schema:isPartOf <https://en.wikipedia.org/> .
  ?item wdt:P21 wd:Q6581072 .
  ?item wdt:P735 ?name .
  ?name wdt:P31 wd:Q12308941
  OPTIONAL {?item wdt:P18 ?image }      
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en" }
}
LIMIT 200
}}--[[User:Jklamo|Jklamo]] ([[User talk:Jklamo|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 17:08, 1 February 2017 (UTC)


::Thank you both. I realised I was actually after women labelled as men - in my correction below, is there a standard means of getting the link to en.wiki to look less hideous? (Images helped, but I've excluded them from this example ... meanwhile gendered given name turns out to be a very poor proxy for gender!) --[[User:Tagishsimon|Tagishsimon]] ([[User talk:Tagishsimon|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 01:56, 2 February 2017 (UTC)
::{{SPARQL|query=SELECT ?item ?itemLabel ?article 
WHERE
{
	?article 	schema:about ?item ;
			schema:isPartOf <https://en.wikipedia.org/> .
  ?item wdt:P21 wd:Q6581097 .
  ?item wdt:P735 ?name .
  ?name wdt:P31 wd:Q11879590
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en" }
}
order by ?itemLabel
}}

== Duplicate items ==

Is it possible to create a list with items that have the same aliasses, labels (and descriptions) as another item in at least 3 languages? [[User:QZanden|Q.Zanden]] <small>[[User talk:QZanden|questions?]]</small> 13:34, 3 February 2017 (UTC)
== Only one specific value ==

Hi, is there any query that can show items which have only one value for a given property? For example, I want all items with P31:Q5 and P31 has no other Qxxs.--[[User:ԱշոտՏՆՂ|ԱշոտՏՆՂ]] ([[User talk:ԱշոտՏՆՂ|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 09:30, 4 February 2017 (UTC)

:A simple solution would be: {{Sparql|query=SELECT ?item {
  {
    SELECT ?item (COUNT(?item) AS ?cnt) {
      ?item p:P106 [ ps:P106 wd:Q42973 ] .
      ?item p:P106 ?valueStatement .
    } GROUP BY ?item
  }
  FILTER(?cnt = 1)
}
}} It does not work for P31:Q5 due to timeouts, so I chose P106:Q42973 here. —[[User:MisterSynergy|MisterSynergy]] ([[User talk:MisterSynergy|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 09:42, 4 February 2017 (UTC)
::Thank you very much, [[User:MisterSynergy|MisterSynergy]].--[[User:ԱշոտՏՆՂ|ԱշոտՏՆՂ]] ([[User talk:ԱշոտՏՆՂ|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 09:51, 4 February 2017 (UTC)

== In en.wiki Category:Libraries_by_region but not having a ==

Hey All, I am looking to try to do a query either on Query Service or Petscan (or another tool if their is a better one), where I get a list of all the articles in the enwiki Category:Libraries by region, that doesn't contain a class or subclass of "Library" in the instance of. I have tried a half dozen different uses of Petscan, but it doesn't appear to be working. Can anyone help? [[User:Sadads|Sadads]] ([[User talk:Sadads|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 15:50, 4 February 2017 (UTC)

:[//petscan.wmflabs.org/?psid=721188 Sure]. But it is probably not very helpful due to flaws in the enwiki category tree. We could try to optimize this query a bit, but it would be useful to know what your task exactly looks like. But I think it will never become a clean set of just libraries without P31/P279*:Q7075 as requested by you.
:Petscan is indeed the best tool for such queries, since it combines data from Wikidata with categorization of a Wikipedia. The query service does not have any information about Wikipedia categorization. You can also use Petscan to add claims in a batch (after you’ve authorized ''Widar''). Regards, —[[User:MisterSynergy|MisterSynergy]] ([[User talk:MisterSynergy|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 16:42, 4 February 2017 (UTC)
::{{ping|MisterSynergy}} Yeah, I wasn't sure how to configure Petscan to do subclassess, but that SPARQL model is super useful gives me a really good way to work from it. Definitely not doing batch edits: I want to do some work cleaning up the category tree on enwiki, and want to see if I can find any more libraries than the 5000 or so we have identified so far per https://tools.wmflabs.org/sqid/#/view?id=Q7075 . It seems like we are way under represented, and the subclasses are way under utilized, even if we consider the information on articles on enwiki. Thanks for the help, and I will see what I can do from here, [[User:Sadads|Sadads]] ([[User talk:Sadads|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 19:37, 4 February 2017 (UTC)
== Comment causes server error ==

A unfortunately quite long query I am writing begins to raise a "Server error" and I don't know why …

If I run the following query as is the server error appears. If I delete line 73 that is commented out anyway it runs … :-(

Any hints why it behaves so strangely or simplifications of the code are very welcome!!

(You'll have to copypaste the code, the link does not seem to work since I had to use <code><nowiki><nowiki></nowiki></code>-tags.)
{{SPARQL|query=
<nowiki>SELECT
  (CONCAT(
  "{{Artwork"
  ,"\n|artist=", IF(BOUND(?artistList), ?artistList, "")
  ,"\n|title="
    , IF(BOUND(?titleDe),(CONCAT("{{de|", ?titleDe, "}}")), "")
    , IF(BOUND(?titleEn),(CONCAT("{{en|", ?titleEn, "}}")), "")
    , IF(BOUND(?titleEs),(CONCAT("{{es|", ?titleEs, "}}")), "")
    , IF(BOUND(?titleFr),(CONCAT("{{fr|", ?titleFr, "}}")), "")
  ,"\n|date=", IF(BOUND(?inceptionStr), ?inceptionStr, "")
  ,"\n|medium=", ?materialList
  ,"\n}}"
  ) as ?outputStr)
  ?templateArtwork
#  ?inceptionStr
WHERE
{{
  SELECT
  ?item
  ?titleDe
  ?titleEn
  ?titleEs
  ?titleFr
  ?inception
  ?inceptionStr
  (GROUP_CONCAT(?artistI; separator="; ") AS ?artistList)
  (GROUP_CONCAT(?materialLabel; separator="; ") AS ?materialList)
  WHERE
  {
    {
    # PUT THE SEARCH QUERY HERE:
    {?item wdt:P217 "CE1131"} UNION
    {?item wdt:P170 wd:Q313163} . # should give 11 results
    }
    
    # artist=
    OPTIONAL { ?item wdt:P170 ?artist . ?artist rdfs:label ?artistLabel . FILTER(lang(?artistLabel)="en") } .
    OPTIONAL { ?artist wdt:P1472 ?creatorPage } .
    BIND(IF(BOUND(?creatorPage),(CONCAT("{{Creator:", STR(?creatorPage), "}}")), ?artistLabel) as ?artistI)

    # date=
    # TODO: precision > 9, <6 not yet implemented
  	OPTIONAL { ?item wdt:P571 ?inception .
               ?item p:P571 ?inceptionStatement .
               ?inceptionStatement psv:P571/wikibase:timePrecision ?inceptionPrecision .
               OPTIONAL { ?inceptionStatement pq:P1480 ?sourcingCircumstance . }
               BIND(CONCAT(
                 "{{Complex date"
                 , " |date1=", CONCAT(STR(YEAR(?inception))
                 , " |precision1=",
                   IF(?inceptionPrecision = 9, "year",
                     IF(?inceptionPrecision = 8, "decade",
                       IF(?inceptionPrecision = 7, "century",
                         IF(?inceptionPrecision = 6, "millennium",
                           "PRECISION <6 IS NOT YET IMPLEMENTED!"))))
                 , IF(BOUND(?sourcingCircumstance) && ?sourcingCircumstance = wd:Q5727902, " |adj1=ca", "")
                 , "}}"
                 )) as ?inceptionStr)
             } .

    # title=
    OPTIONAL { ?item rdfs:label ?titleDe . FILTER(lang(?titleDe)="de") } .
    OPTIONAL { ?item rdfs:label ?titleEn . FILTER(lang(?titleEn)="en") } .
    OPTIONAL { ?item rdfs:label ?titleEs . FILTER(lang(?titleEs)="es") } .
    OPTIONAL { ?item rdfs:label ?titleFr . FILTER(lang(?titleFr)="fr") } .

    # medium=
    OPTIONAL { ?item wdt:P186 ?material . ?material rdfs:label ?materialLabel . FILTER(lang(?materialLabel)="en") } .

    # institution=
    OPTIONAL { ?item wdt:P195 ?institution . ?institution rdfs:label ?institutionLabel . FILTER(lang(?institutionLabel)="en") } .
    OPTIONAL { ?institution wdt:P1612 ?institutionPage } .
####    BIND(IF(BOUND(?institutionPage),(CONCAT("{{Institution:", STR(?institutionPage), "}}")), ?institutionLabel) as ?institutionI)
  }
  GROUP BY
  ?item
  ?titleDe
  ?titleEn
  ?titleEs
  ?titleFr
  ?inception
  ?inceptionStr
  ORDER BY ?item
  }
#	?item wdt:P170 wd:Q313163 . # NO NEED FOR THIS!
	SERVICE wikibase:label {bd:serviceParam wikibase:language "en,de,es,fr" .
                            ?artist rdfs:label ?artistLabel .
                           }
}
</nowiki>}}

Thanks, --[[User:Marsupium|Marsupium]] ([[User talk:Marsupium|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 20:00, 30 January 2017 (UTC)
:{{ping|Marsupium}} Your query is just (a little) to long. Shorting it by a bit, eg. by deleting some comments or maybe white space, will make it work again. Related tasks: [[phab:T112151|T112151]], [[phab:T125299|T125299]]. Cheers, [[User:Hoo man|Hoo man]] ([[User talk:Hoo man|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 14:58, 31 January 2017 (UTC)
::Ah, okay! Thanks a lot! --[[User:Marsupium|Marsupium]] ([[User talk:Marsupium|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 10:43, 5 February 2017 (UTC)

== GeoJSON ==

Hey. [https://query.wikidata.org/#%23defaultView%3AMap%0ASELECT%20DISTINCT%20%3Fitem%20%3FitemLabel%20%3Fcoords%20%7B%0A%20%20%20%09VALUES%20%3Fitemclass%20%7B%20wd%3AQ5710433%20wd%3AQ132821%20%7D%0A%20%20%20%20%3Fitem%20wdt%3AP31%2Fwdt%3AP279%2a%20%3Fitemclass%20%20.%0A%20%20%20%20wd%3AQ1218%20wdt%3AP625%20%3Fjerusalemloc%20.%0A%0A%20%20%20%20SERVICE%20wikibase%3Aaround%20%7B%0A%20%20%20%20%20%20%3Fitem%20wdt%3AP625%20%3Fcoords%20.%0A%20%20%20%20%20%20bd%3AserviceParam%20wikibase%3Acenter%20%3Fjerusalemloc%20.%20%0A%20%20%20%20%20%20bd%3AserviceParam%20wikibase%3Aradius%20%2215%22%20.%20%0A%20%20%20%20%7D%20%0A%0A%20%20SERVICE%20wikibase%3Alabel%20%7B%20%20%0A%20%20%20%20bd%3AserviceParam%20wikibase%3Alanguage%20%22he%22%20.%20%20%0A%20%20%7D%20%20%20%0A%7D Just created a map] of terror attacks in Jerusalem and I was wondering if I could download this map as GeoJSON in order to use it in [[:mw:Help:Extension:Kartographer]]--[[User:Mikey641|Mikey641]] ([[User talk:Mikey641|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 13:20, 8 February 2017 (UTC)
:I'm not aware of such a function but it might not even necessary to do the detour via GeoJSON. The Kartographer extension can be fed directly with a SPARQL query (e.g. [[:mw:Help:Extension:Kartographer#GeoShapes via Wikidata Query]]) but I don't know how it works in detail. --[[User:Pasleim|Pasleim]] ([[User talk:Pasleim|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 13:19, 10 February 2017 (UTC)

== Works named for living persons ==

Especially films which were devoted to living persons (i.e. published when a person was still living). Can I have a list of it? --[[User:Infovarius|Infovarius]] ([[User talk:Infovarius|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 16:43, 8 February 2017 (UTC)
:{{SPARQL|query=SELECT DISTINCT ?item ?itemLabel ?denoted ?denotedLabel  WHERE{
  ?item wdt:P31/wdt:P279* wd:Q11424;
        (wdt:P921|wdt:P138) ?denoted;
        wdt:P577 ?published.
  ?denoted wdt:P31 wd:Q5;
         wdt:P569 ?birth.
  OPTIONAL{
    ?denoted wdt:P570 ?death .
  }
  FILTER(?death > ?published || !bound(?death))
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en" }         
}
}} --[[User:Pasleim|Pasleim]] ([[User talk:Pasleim|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 13:05, 10 February 2017 (UTC)
== Queries related to time of item and property creation ==

Hi, We are [[c:Commons_talk:Photo_challenge#Preparing_the_.22undocumented.22_challenge|discussing]] a new [[Q15733209|photo challenge]] for best photographs for "undocumented" places, or places with Wikidata item but no images on Commons. One of the requirements we would like to have is that those will be new images are for existing items. One query we would need to flag potential images that do not meet the challenge requirements, would be a query to capture the date of item creation and the dates of {{P|373}} and {{P|18}} creation (if present). Do we have a way to do such queries in SPARQL or is it something we would need [https://quarry.wmflabs.org/ quarry] for? --[[User:Jarekt|Jarekt]] ([[User talk:Jarekt|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 14:35, 6 February 2017 (UTC)
:Information about an item history is not available by the query service, so you have quarry. --[[User:Pasleim|Pasleim]] ([[User talk:Pasleim|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 13:11, 10 February 2017 (UTC)
::Thank you I will try to figure it out in SQL. --[[User:Jarekt|Jarekt]] ([[User talk:Jarekt|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 14:30, 14 February 2017 (UTC)

== Featured Wikipedia Articles ==

I'm wondering if you can send me a '''SPARQL code''' which gives me a list of '''featured wikipedia articles''' in one language, that do not exist on another language (for example feature enwiki with no existence in frwiki) of the '''same category''' (e.g. mathematics). That would be awesome and appreciated. --[[User:Sky xe|Sky xe]] ([[User talk:Sky xe|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 22:48, 12 February 2017 (UTC)
:Not possible with SPARQL since it doesn't have access to wiki categories. But you can use SPARQL queries in [[petscan:|PetScan]]. [[User:Matěj Suchánek|Matěj Suchánek]] ([[User talk:Matěj Suchánek|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 16:17, 13 February 2017 (UTC)
:PetScan WikiProject based query [https://petscan.wmflabs.org/?psid=736912] (0 results). --[[User:Jklamo|Jklamo]] ([[User talk:Jklamo|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 18:13, 13 February 2017 (UTC)
Would it be possible to list all items with a certain badge in xyzwiki? That could help to identify missing or misplaced badges for a certain wiki. -- [[User:Innocent bystander|Innocent bystander]] ([[User talk:Innocent bystander|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 18:53, 13 February 2017 (UTC)
:{{sparql|query=SELECT ?item ?itemLabel ?article WHERE {
  ?item ^schema:about ?article .
  ?article wikibase:badge wd:Q17437796; schema:isPartOf <https://fr.wikipedia.org/> .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en" }
}
limit 100
}}--[[User:Edgars2007|Edgars2007]] ([[User talk:Edgars2007|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 08:40, 14 February 2017 (UTC)

Thanks for the answers. I used PetScan before to find missing articles of certain categories, but I still don't know how to make my output only includes featured or good articles (badge), that's why I thought it might be possible using SPARQL directly. I have got a code from the wiki data presentation of [https://meta.wikimedia.org/wiki/User:Asaf_(WMF) Asaf Bartov] which gives featured articles of African Women on enwiki with no corresponding articles on the frwiki. What is needed now, is just a modification to do it with categories (if possible). I posted the code on my user page: [https://commons.wikimedia.org/wiki/User:Sky_xe] --[[User:Sky xe|Sky xe]] ([[User talk:Sky xe|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 00:44, 14 February 2017 (UTC)
:Something like [[petscan:737773|this]]. --[[User:Edgars2007|Edgars2007]] ([[User talk:Edgars2007|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 08:50, 14 February 2017 (UTC)
:really awesome. That is what I wanted. Thank you Edgars --[[User:Sky xe|Sky xe]] ([[User talk:Sky xe|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 05:17, 15 February 2017 (UTC)
== Why isn't bubblechart showing? ==

Hello, I have this query to show gender balance in Basque Wikipedia biography articles. But I can't get it to show BubbleChart visualization. Could someone explain me why?

{{SPARQL|query=
#Euskarazko Wikipediako biografien genero oreka

PREFIX schema: <http://schema.org/>

SELECT ?gender (count(distinct?human) as ?number)
WHERE
{
	?human wdt:P31 wd:Q5
	; wdt:P21 ?gender.
    ?wikilink schema:about ?human.
    ?wikilink schema:isPartOf <https://eu.wikipedia.org/>.
}
GROUP BY ?gender
LIMIT 6
}}

Thanks. -[[User:Theklan|Theklan]] ([[User talk:Theklan|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 20:43, 15 February 2017 (UTC)
:This one works (changed ?gender -> ?genderLabel):
:{{sparql|query=
#defaultView:BubbleChart
#Euskarazko Wikipediako biografien genero oreka
SELECT ?genderLabel (count(distinct?human) as ?number)
WHERE
{
	?human wdt:P31 wd:Q5
	; wdt:P21 ?gender.
    ?wikilink schema:about ?human.
    ?wikilink schema:isPartOf <https://eu.wikipedia.org/>.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "eu" }
}
GROUP BY ?genderLabel
LIMIT 6
}}--[[User:Edgars2007|Edgars2007]] ([[User talk:Edgars2007|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 15:22, 16 February 2017 (UTC)
::{{ping|Edgars2007}} Great! I tried exactly that and it gave an error . -[[User:Theklan|Theklan]] ([[User talk:Theklan|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 19:48, 16 February 2017 (UTC)

Hi, i am trying to do a query which would give qualifiers from under the some properties from some items.

== How to get unspecified list of qualifiers? ==

Example would be return all candidates for some election and return property {{P|P726}} with all it's qualifiers. (Example item: {{Q|Q16171493}} and {{P|726}})

<source lang="sparql">
 SELECT ?electionLabel ?candidateLabel ?candidate WHERE {
  ?candidate wdt:P726 ?election.
  ?election wdt:P361 wd:Q640715.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fi". } 
 }
</source>

--[[User:Zache|Zache]] ([[User talk:Zache|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 04:12, 17 February 2017 (UTC)
:It's not possible (anyway, I don't know a way how) to make columns dynamic, so I had to make it look like this:
:{{SPARQL|query=SELECT ?candidate ?candidateLabel ?electionLabel ?qualifiers WITH {
  SELECT ?candidate ?election (GROUP_CONCAT(CONCAT(STR(?qpropLabel), ': ', COALESCE(STR(?qvalueLabel), STR(?qvalue))); separator='; ') AS ?qualifiers) {
    ?candidate p:P726 ?statement .
    ?statement ps:P726 ?election .
    ?election wdt:P361 wd:Q640715 .
    OPTIONAL {
      ?statement ?pq ?qvalue .
      ?qprop wikibase:qualifier ?pq .
      OPTIONAL {
        ?qprop wikibase:propertyType wikibase:WikibaseItem .
        ?qvalue rdfs:label ?qvalueLabel .
        FILTER( LANG( ?qvalueLabel ) = "fi" ) .
      }
    } .
    SERVICE wikibase:label {
      bd:serviceParam wikibase:language "fi" .
      ?qprop rdfs:label ?qpropLabel .
    } .
  } GROUP BY ?candidate ?election
} AS %subquery WHERE {
  INCLUDE %subquery .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fi" } .
} }}
:[[User:Matěj Suchánek|Matěj Suchánek]] ([[User talk:Matěj Suchánek|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 20:01, 17 February 2017 (UTC)
== P27 = Q801 and born before 1948 ==

Thank you. --[[User:Thibaut120094|Thibaut120094]] ([[User talk:Thibaut120094|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 14:37, 20 February 2017 (UTC)
:{{SPARQL|query=SELECT ?item WHERE{
  ?item wdt:P27 wd:Q801;
        wdt:P569 ?birth .
  FILTER(YEAR(?birth) < 1948)
}  
}} --[[User:Pasleim|Pasleim]] ([[User talk:Pasleim|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 14:58, 20 February 2017 (UTC)
::{{ping|Thibaut120094}} someone could come to israel even if they weren't born in it. For example, most russians who live in israel came to israel in 1991. It would be better to replace p569 in {{P|570}}--[[User:Mikey641|Mikey641]] ([[User talk:Mikey641|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 15:02, 20 February 2017 (UTC)

== Demonym of a country(P1549) for a particular language ==

For example, the demonym of Canada in English should just return "Canadian".
How would I go about doing this?
SERVICE wikibase:label { bd:serviceParam wikibase:language "en" } does not work on demonym labels.
: You should use FILTER and LANG on P1549:
{{SPARQL|query=SELECT ?demonym
WHERE {
  wd:Q16 wdt:P1549 ?demonym .
  FILTER (LANG(?demonym) = "en") .
}
}} -- [[User:Envlh|Envlh]] ([[User talk:Envlh|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 13:15, 21 February 2017 (UTC)
Thanks! [[User:Mitsubayashi13|Mitsubayashi13]] ([[User talk:Mitsubayashi13|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 02:02, 22 February 2017 (UTC)

== A query that lists all the articles in a specific language whose WD items have less than 10 statements ==

Hello SPARQL magicians, could you help us by constructing a WD query that will generate a list of all the articles in X language (say, Hebrew :)), for which the WD items have less than Y statements (say, 10)? This request is from a WD newbie in the Hebrew Community. I did look for variations in the query examples, but could't find anything relevant. Am I missing anything..? Does something similar already exists? Thanks in advance for your help with this. Best, [[User:Esh77|Shani Evenstein]] ([[User talk:Esh77|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 18:58, 21 February 2017 (UTC)
: {{SPARQL|query=
SELECT ?item ?itemLabel ?article ?statementCount WHERE {
  VALUES (?project ?maxStatementCount ?labelLanguage) {
    (<https://he.wikipedia.org/> 10 "he") # adjust language and count here
    # URL above must be https:// and include the trailing / !
  }
  ?article a schema:Article;
           schema:about ?item;
           schema:isPartOf ?project.
  ?item wikibase:statements ?statementCount.
  OPTIONAL { ?item rdfs:label ?itemLabel. FILTER(LANG(?itemLabel) = ?labelLanguage). }
  FILTER(?statementCount < ?maxStatementCount).
}
LIMIT 1000
}} --[[User:TweetsFactsAndQueries|TweetsFactsAndQueries]] ([[User talk:TweetsFactsAndQueries|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 20:22, 21 February 2017 (UTC)
::Thanks much! Will do! :) [[User:Esh77|Shani Evenstein]] ([[User talk:Esh77|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 22:41, 21 February 2017 (UTC)

== Women educated at or employed by an educational institute within a country ==

I have a query I use as the basis of a Listeria report, listing all women educated at or employed by a named educational institute - in the example below, the subject institute is {{Q|Q1247589}}

Please help me to amend the report so as to list all women with no en.wiki biog, educated at or employed by an educational institute within a country ... i.e. I wish to specify the country, and get all pertinent items, where the item has an educated at or employed by property pointing to an educational institution within that country. (For educated at, I think we can just check the linked item is within the country. For employed by, we'd need to know that the item is an educational institute and that it is within the country. I'd settle for just 'educated at'. if 'employed by' is too difficult.) thanks --[[User:Tagishsimon|Tagishsimon]] ([[User talk:Tagishsimon|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 20:51, 21 February 2017 (UTC)

: {{SPARQL|query=
SELECT ?item WHERE {
	?item wdt:P21 wd:Q6581072 .
        { ?item wdt:P69 wd:Q1247589 }
        union
        { ?item wdt:P108 wd:Q1247589 }
    OPTIONAL {
    ?wiki0 <http://schema.org/about> ?item .
    FILTER(SUBSTR(STR(?wiki0),1,24) = 'https://en.wikipedia.org') .
    }
  FILTER(!bound(?wiki0))
}
}}
== Search for with subclass depth, first image and return labels in all languages ==

Hello SPARQL magicians and experts, I've been trying for 2 days and went through all examples. I need your help figuring out a complicated query that I haven't found an example close to  

The idea is to search for sports, get the first image (if one is found).  and retrieve the labels in all languages.  Below I achieved a small part but here are the problems.  

1-  with this query, I'm able to get basketball but not football, I cannot figure out how to make search with subclass as footbal is a subclass of type of sports, I thought I had it working right but it doesn't return football.

2- when I add to fetch image (tried with optional), it returns "bodybuilding" in 2 rows because there are 2 images for boxing, is there a way to get the first one row with first image only.  I tried distinct and didn't get far with it.

3- In this case I'm searching in English but would like to get back labels in all languages.

The perfect result out of this would be 10 rows where each row would be 1 sport starting with "bo", first image and labels in all languages, I understand that it might be a tall order so maybe languages would have to be requested in another query and if so, how?

{{SPARQL|query=
#NOT WORKING AS EXPECTED/Need Help 
SELECT DISTINCT ?item ?label WHERE {  		 
   ?item wdt:P31/wdt:P279* wd:Q31629. 		
   ?item rdfs:label ?label. 		 
   FILTER((LANG(?label)) = "en") 		 
   FILTER(STRSTARTS(lcase(?label), lcase("bo"))) 		
 } 		 
LIMIT 10
}}
{{unsigned|Safwanhak|21. 2. 2017, 22:40‎}}
:''sport starting with "bo"'' – ''football'' starts with ''fo''. [[User:Matěj Suchánek|Matěj Suchánek]] ([[User talk:Matěj Suchánek|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 17:30, 22 February 2017 (UTC)

Sorry if it wasn't clear  [[User:Matěj Suchánek|Matěj Suchánek]] but as you can see my questions talks about both "fo" and "bo";  the question is still valid.{{unsigned|Safwanhak|22. 2. 2017, 18:11}}
: I'm not able to handle the third mentioned problem and am curious as well about how to dynamically change exported variables (as this is the only way how to fetch the labels).
: I think the cause of the first problem could be the <code>LIMIT</code> you are applying. The second point needs to be solved by doing multiple chained queries:
:{{SPARQL|query=SELECT ?item ?image ?label WITH {
  SELECT ?item (SAMPLE(?p18) AS ?image) {
    ?item wdt:P31/wdt:P279* wd:Q31629 .
    OPTIONAL { ?item wdt:P18 ?p18 } .
  } GROUP BY ?item
} AS %subquery WHERE {
  INCLUDE %subquery .
  ?item rdfs:label ?label .
  FILTER ( LANG( ?label ) = "en" ) .
  #FILTER ( STRSTARTS( LCASE( ?label ), "bo" ) ) .
} }}
:[[User:Matěj Suchánek|Matěj Suchánek]] ([[User talk:Matěj Suchánek|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 20:28, 22 February 2017 (UTC)

== Items with a specific property ==

How do I find all items with a specific property? In particular, I want all items that have the [[Property:P961|IPNI property]] set. Might it be good to add a trivial example like this to the list of examples? [[User:HYanWong|HYanWong]] ([[User talk:HYanWong|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 09:23, 22 February 2017 (UTC)

:{{SPARQL|query=SELECT ?item { ?item p:P961 [] . } }} If you’d like to see the values as well, use the query <code>SELECT ?item ?value { ?item p:P961 [ ps:P961 ?value ] . }</code>. —[[User:MisterSynergy|MisterSynergy]] ([[User talk:MisterSynergy|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 10:58, 22 February 2017 (UTC)
::Perfect, thanks. [[User:HYanWong|HYanWong]] ([[User talk:HYanWong|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 11:43, 22 February 2017 (UTC)
: I normally use <code>SELECT ?item ?value { ?item p:P961 ?value. }</code>, but with square brackets is much faster (6540 ms vs 23359 ms) , good to know. --[[User:ValterVB|ValterVB]] ([[User talk:ValterVB|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 18:00, 22 February 2017 (UTC)
== Labels <math>\ \neq </math> Sitelink ==

Hey. I was wondering if it's possible to create a list of items using SPARQL in which the wikidata label isn't like the sitelink (in hewiki).<br />
for example if the label is "ABC" but sitelink is "DEF" it will appear, but if both the sitelink and the label are "ABC" it won't appear.<br />
Thanks--[[User:Mikey641|Mikey641]] ([[User talk:Mikey641|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 22:31, 4 February 2017 (UTC)

:{{Sparql|query=SELECT ?item ?hewiki_sitelink ?he_label {
  ?hewiki_sitelink schema:about ?item; schema:isPartOf <https://he.wikipedia.org/> .
  ?item rdfs:label ?he_label .
  FILTER(LANG(?he_label) = 'he') .
  
  FILTER(false = (SUBSTR(STR(?hewiki_sitelink), 31) = ENCODE_FOR_URI(STR(?he_label))) ) .
} LIMIT 5000
}} It is limited to 5.000 items to avoid timeouts. For full results you could possibly omit the final <code>FILTER</code> command, download full data to your machine and perform the comparison offline with a small script. But basically: yes, this is possible. —[[User:MisterSynergy|MisterSynergy]] ([[User talk:MisterSynergy|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 07:26, 5 February 2017 (UTC)
:: It's case sensitive, probably is necessary change it in case insensitive. --[[User:ValterVB|ValterVB]] ([[User talk:ValterVB|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 08:00, 5 February 2017 (UTC)

:::Good point for many languagues/scripts, but for Hebrew language I am not sure whether it has case sensitivity at all. If so, replace the last <code>FILTER</code> command by <code>FILTER(false = (LCASE(SUBSTR(STR(?hewiki_sitelink), 31)) = LCASE(ENCODE_FOR_URI(LCASE(STR(?he_label))))) ) .</code>. This works for ''most'', but not all label/sitelinks combinations, although it is not at all a beautiful solution. It is a bit difficult here that the sitelinks come URL-encoded, while the labels do not. Unfortunately I do not find a function to URL decode an encoded URL to a plain string, which would be helpful here. —[[User:MisterSynergy|MisterSynergy]] ([[User talk:MisterSynergy|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 08:24, 5 February 2017 (UTC)
::::There wasn't such function at SPARQL.--[[User:Edgars2007|Edgars2007]] ([[User talk:Edgars2007|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 08:33, 5 February 2017 (UTC)

:::::That was my assumption. I usually use [https://www.w3.org/TR/sparql11-query/ this reference] and it does not list any useful decoding function. It might be better anyway to download full plain results from sparql (qitem+sitelink+label) and perform the comparison offline with a more powerful script. —[[User:MisterSynergy|MisterSynergy]] ([[User talk:MisterSynergy|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 08:44, 5 February 2017 (UTC)
:::::: See my comment at [[#Sitelinks]]. [[User:Matěj Suchánek|Matěj Suchánek]] ([[User talk:Matěj Suchánek|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 08:52, 5 February 2017 (UTC)

:::::::Ah, cool! <code>schema:name</code> simplifies the query to {{Sparql|query=SELECT ?item ?hewiki_sitelink ?sitelink_label ?he_label {
  ?hewiki_sitelink schema:about ?item; schema:isPartOf <https://he.wikipedia.org/>; schema:name ?sitelink_label .
  ?item rdfs:label ?he_label .
  FILTER(LANG(?he_label) = 'he') .
  FILTER(false = (?sitelink_label = ?he_label) ) .
} LIMIT 5000
}} This is still case sensitive, but it avoids all URL encoding problems. —[[User:MisterSynergy|MisterSynergy]] ([[User talk:MisterSynergy|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 09:14, 5 February 2017 (UTC)
: Yes, work also with case insensitive version. Just to complicate matters: you can exclude the items with a parenthesis in the Sitelinks to exclude disambiguation? --[[User:ValterVB|ValterVB]] ([[User talk:ValterVB|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 10:03, 5 February 2017 (UTC)
:: Found it: case insensitive and without ")" in sitelink: {{Sparql|query=SELECT ?item ?wiki_sitelink ?sitelink_label ?label {
  ?wiki_sitelink schema:about ?item; schema:isPartOf <https://it.wikipedia.org/>; schema:name ?sitelink_label .
  ?item rdfs:label ?label .
  FILTER(LANG(?label) = 'it') .
  FILTER(false = (LCASE(SUBSTR(STR(?wiki_sitelink), 31)) = LCASE(ENCODE_FOR_URI(LCASE(STR(?label))))) )
  FILTER(false=CONTAINS(?sitelink_label,")"))
} LIMIT 100}} --[[User:ValterVB|ValterVB]] ([[User talk:ValterVB|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 10:16, 5 February 2017 (UTC)
:::[[User:ValterVB|ValterVB]], [[User:Matěj Suchánek|Matěj Suchánek]] thank you very much!!! you really helped me--[[User:Mikey641|Mikey641]] ([[User talk:Mikey641|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 17:48, 7 February 2017 (UTC)
:::: Something go wrong when I change it->ru. It gives many absolutely equal words... --[[User:Infovarius|Infovarius]] ([[User talk:Infovarius|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 09:40, 9 February 2017 (UTC)

:::::{{Ping|Infovarius}} {{SPARQL|query=SELECT ?item ?wiki_sitelink ?sitelink_label ?label {
  ?wiki_sitelink schema:about ?item; schema:isPartOf <https://ru.wikipedia.org/>; schema:name ?sitelink_label .
  ?item rdfs:label ?label .
  FILTER(LANG(?label) = 'ru') .
  FILTER(false = (LCASE(?sitelink_label) = LCASE(?label)) ) .
  FILTER(false = CONTAINS(?sitelink_label, ')') ) .
} LIMIT 100
}} This should work. —[[User:MisterSynergy|MisterSynergy]] ([[User talk:MisterSynergy|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 09:44, 9 February 2017 (UTC)

{{ping|ValterVB}}: You shouldn't exclude items with parentheses, because not all such are disambiguation pages. You should cut out the parenthesized part. Else you'd exclude https://en.wikipedia.org/wiki/Georgia_(country) for example

And why do you guys use this strange filter(false=(x=y))? Use filter(x<>y) --[[User:Vladimir Alexiev|Vladimir Alexiev]] ([[User talk:Vladimir Alexiev|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 16:46, 23 February 2017 (UTC)

: {{ping|Vladimir Alexiev}} Yes, but if I don't exclude them  I have too many results to check. About the strange filter I'm not expert but I copy a lot :) so I don't know if exist a more efficient filter. --[[User:ValterVB|ValterVB]] ([[User talk:ValterVB|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 17:09, 23 February 2017 (UTC)
:: It's the same as efficiency, but harder to read. My name is not inconceivably: --[[User:Vladimir Alexiev|Vladimir Alexiev]] ([[User talk:Vladimir Alexiev|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 17:32, 23 February 2017 (UTC)

== Alias = label ==

Hey. Is there any way to find a list of items in which the Alias = label? thanks--[[User:Mikey641|Mikey641]] ([[User talk:Mikey641|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 20:25, 22 February 2017 (UTC)
:{{SPARQL|query=SELECT ?item ?label WHERE{
  ?item rdfs:label ?label FILTER(lang(?label) = 'en') .
  ?item skos:altLabel ?alias FILTER (LANG (?alias) = 'en')
  FILTER(?label = ?alias)
} LIMIT 100
}} --[[User:Pasleim|Pasleim]] ([[User talk:Pasleim|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 13:53, 23 February 2017 (UTC)

== External Identifiers used for Companies ==

Trying to find all External Identifier props used for Companies.
This finds all external identifier props:

{{sparql|query=
select ?wd ?lab ?desc {
  ?wd wikibase:directClaim ?wdt.
  ?wdt a owl:DatatypeProperty 
  filter (exists{?wd wdt:P31/wdt:P279* wd:Q19847637} # Unique Identifier
      {{!}}{{!}} exists{?wd wikibase:propertyType wikibase:ExternalId})
  #filter exists {[?wdt []; wdt:P31/wdt:P279* wd:Q783794]} # a Company: causes timeout
  ?wd rdfs:label ?lab filter(lang(?lab)="en")
  optional {?wd schema:description ?desc filter(lang(?desc)="en")}
}
}}

But if I uncomment the part about Company, I get a timeout.
The bracketry is probably confusing, so we can expand it like this for clarity:
<pre>
   filter exists {?company ?wdt ?any_prop; wdt:P31/wdt:P279* wd:Q783794}
</pre>
--[[User:Vladimir Alexiev|Vladimir Alexiev]] ([[User talk:Vladimir Alexiev|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 17:05, 23 February 2017 (UTC)
== controlling the use of {{P|P1889}} ==

Can one of you make a query that list items that use P1889 but the page they refer to, does not have that property. [[User:QZanden|Q.Zanden]] <small>[[User talk:QZanden|questions?]]</small> 11:14, 14 February 2017 (UTC)
:{{sparql|query=
select ?item ?itemLabel ?item2 ?item2Label where {
  ?item wdt:P1889 ?item2 .
  filter not exists { ?item2 wdt:P1889 [] }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en,de,fr" }
  }
limit 1000
}}
:?item2 is the item, which doesn't have P1889. --[[User:Edgars2007|Edgars2007]] ([[User talk:Edgars2007|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 12:52, 14 February 2017 (UTC)
::Thank you! Is it possible to do this with a bot, instead of doing everything manual? [[User:QZanden|Q.Zanden]] <small>[[User talk:QZanden|questions?]]</small> 19:40, 14 February 2017 (UTC)
:::Is it possible - yes, it's trivial. I'm simply not sure, that we have to do that. IMHO, it's more important to have this claim at the ''other'' item (in SPARQL query - ?item). The claim on ?item2 isn't so important. But I really don't have strong oppinion. --[[User:Edgars2007|Edgars2007]] ([[User talk:Edgars2007|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 09:41, 15 February 2017 (UTC)
:: I suppose that there needn't to be the same property at ''other'' item, sometimes it's sufficient to have some ''another'' property (like {{P|279}} or {{P|361}} or other) which would show that they are not the same. --[[User:Infovarius|Infovarius]] ([[User talk:Infovarius|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 19:55, 20 February 2017 (UTC)
::: {{ping|Infovarius|Edgars2007}} "different from" is declared instance of: symmetric property. So why do you argue in some cases it's "not important" to have it in the other direction? --[[User:Vladimir Alexiev|Vladimir Alexiev]] ([[User talk:Vladimir Alexiev|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 16:53, 23 February 2017 (UTC)
:::: See, for example, {{Q|11634}}: one doesn't need {{P|1889}} {{Q|860861}} because there is {{P|1056}} with this value already. And it doesn't depend whether {{Q|860861}} contains {{P|1889}} {{Q|11634}} or not. Of course, formally (and even, technically) one can add {{P|1889}} too, but I regard it as redundant. --[[User:Infovarius|Infovarius]] ([[User talk:Infovarius|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 23:19, 23 February 2017 (UTC)

== Time zone locations on map ==

I would like to have a query where for a given time zone (e.g. UTC+1) all the locations are displayed on a map. Thank you in advance! [[User:Steak|Steak]] ([[User talk:Steak|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 14:31, 22 February 2017 (UTC)
:{{SPARQL|query=
#defaultView:Map
SELECT ?item ?coord {
  ?item wdt:P421 wd:Q6655;
        wdt:P625 ?coord .
} }}
:Be careful, there are 123,000+ results, it may crash your browser. [[User:Matěj Suchánek|Matěj Suchánek]] ([[User talk:Matěj Suchánek|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 20:32, 22 February 2017 (UTC)
::Thank you! [[User:Steak|Steak]] ([[User talk:Steak|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 19:56, 23 February 2017 (UTC)

== Listeria - how to show interlanguage links ==

Consider a Lisetria list such as https://en.wikipedia.org/wiki/Wikipedia:WikiProject_Women_in_Red/Missing_articles_by_education/Spain_-_Complutense_University_of_Madrid ... how can I add a column showing whether or not there is an es.wiki article on the subject? How can I add a column or columns showing interlanguage links to other languages? thanks --[[User:Tagishsimon|Tagishsimon]] ([[User talk:Tagishsimon|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 21:17, 22 February 2017 (UTC)
:You can export arbitrary data from SPARQL to Listeria by adding the variable to the <code>SELECT</code> clause, then you have to expand the <code>columns=</code> parameter with <code>,?variable:column name</code>. See also [[Template:Wikidata list|the documentation]]. [[User:Matěj Suchánek|Matěj Suchánek]] ([[User talk:Matěj Suchánek|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 20:01, 23 February 2017 (UTC)

== Finding property values with the same string in them ==

I'm working on matching {{P|1614}} into Wikidata. This is an unusual resource because it's divided up into volumes by date, and so a single person may appear in two or three volumes if their career spanned both periods. However, no-one should have two entries in the ''same'' volume, and I'd like to construct a query to find these.

Because of the way the URLs are constructed ([volume]/member/[name]) this means that I need to find any entry with:

* more than one P1614
* ...two of which start with the same string (if it helps, the eight volumes are [1386-1421, 1509-1558, 1558-1603, 1604-1629, 1660-1690, 1690-1715, 1715-1754, 1754-1790, 1790-1820, 1820-1832])

Is it possible to write a query to look for this? (As a test case, {{Q|312591}} should show up - there is a bug in the source URLs and so he's listed twice in 1820). [[User:Andrew Gray|Andrew Gray]] ([[User talk:Andrew Gray|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 13:32, 23 February 2017 (UTC)
:{{SPARQL|query=SELECT ?item ?value1 ?value2 WHERE{
  ?item wdt:P1614 ?value1;
        wdt:P1614 ?value2 .
  FILTER(?value1 < ?value2)
  FILTER(substr(?value1, 0, 9) = substr(?value2, 0, 9))
}
}} --[[User:Pasleim|Pasleim]] ([[User talk:Pasleim|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 13:46, 23 February 2017 (UTC)

::Awesome, thanks! Works a charm (and finds an error I'd missed, which is exactly what I was hoping for) [[User:Andrew Gray|Andrew Gray]] ([[User talk:Andrew Gray|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 20:20, 23 February 2017 (UTC)
== schema:name ==

This is not directly a request for a query, but related to SPARQL querying. As I learnt by [[User:Matěj Suchánek|Matěj Suchánek]] recently, there is a (newly introduced) feature to access the lemma (Wikipedia page title) of sitelinks via <code>schema:name</code>. To my knowledge it is roughly used like this: <code>?wikilink schema:about ?item; schema:name ?lemma</code>.

Unfortunately there is only sparse documentation about <code>schema:name</code> available and I do not fully understand how it works. Is it supposed to be available for any sitelink, or only in some special cases? In [//query.wikidata.org/#SELECT%20%3Fitem%20%3Flemma%20%7B%0A%20%20%3Fitem%20wdt%3AP2566%20%3Fidentifier%20.%0A%20%20%3Fwikilink%20schema%3Aabout%20%3Fitem%3B%20schema%3AisPartOf%20%3Chttps%3A%2F%2Fde.wikipedia.org%2F%3E.%0A%20%20OPTIONAL%20%7B%0A%20%20%20%20%3Fwikilink%20schema%3Aname%20%3Flemma%20.%0A%20%20%7D%0A%7D this SPARQL query] only ~900 out of ~6600 sitelinks have a value, so why is it missing for most sitelinks? Thanks, [[User:MisterSynergy|MisterSynergy]] ([[User talk:MisterSynergy|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 06:09, 11 February 2017 (UTC)
:Maybe all the triples haven't been updated yet. Compare:
:{{SPARQL|query=SELECT (COUNT(*) AS ?count) { ?sitelink schema:about [] } }}
:and
:{{SPARQL|query=SELECT (COUNT(*) AS ?count) { ?sitelink schema:name [] } }}
:The numbers are still changing. [[User:Matěj Suchánek|Matěj Suchánek]] ([[User talk:Matěj Suchánek|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 09:16, 11 February 2017 (UTC)

::Thanks for the answer. I am going to try this again at some point in the future. —[[User:MisterSynergy|MisterSynergy]] ([[User talk:MisterSynergy|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 09:37, 11 February 2017 (UTC)

{{ping|MisterSynergy}} There's probably >100M sitelinks on WD, so don't expect the query to easily count them all. Try your query on some restricted set --[[User:Vladimir Alexiev|Vladimir Alexiev]] ([[User talk:Vladimir Alexiev|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 16:49, 23 February 2017 (UTC)
:According to one of the queries by Matěj Suchánek above there should be ~55M sitelinks. I was not planning to query all of them at once, of course :-) Just as a subsequent filter to a query that results in some thousand items. --[[User:MisterSynergy|MisterSynergy]] ([[User talk:MisterSynergy|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 12:22, 24 February 2017 (UTC)

== Items with P106 but no Q5 in catalan wikipedia ==

I know it begins with <code>?person wdt:P106 [] .</code> but I don't know how to do the rest. Thanks, [[User:Paucabot|Paucabot]] ([[User talk:Paucabot|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 10:14, 25 February 2017 (UTC)
:{{SPARQL|query=SELECT distinct ?cawiki_sitelink ?item {
  ?cawiki_sitelink schema:about ?item; schema:isPartOf <https://ca.wikipedia.org/> .
  ?item wdt:P106 [] .
  filter not exists {?item wdt:P31 wd:Q5 }
} LIMIT 5000
}}
:Be aware, that many(?) items are fictional characters. --[[User:Edgars2007|Edgars2007]] ([[User talk:Edgars2007|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 13:53, 25 February 2017 (UTC)
:: Thanks! [[User:Paucabot|Paucabot]] ([[User talk:Paucabot|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 16:29, 25 February 2017 (UTC)

== Male tennis players without an ATP ID ==

Hi, I'm trying to create a list of male (P21) tennis players (P106 = Q10833314), born before 1950, who do not have a value for the ATP ID property (P536). Tried the following query but it did not return any records. --[[User:Wolbo|Wolbo]] ([[User talk:Wolbo|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 13:50, 25 February 2017 (UTC)

{{sparql|query=
#Male tennis players who were born before 1950 without an atp id
#Draft

SELECT ?player ?date ?cause ?player_label ?atp_id
WHERE 
{
	?player wdt:P106 wd:Q10833314 .    # find items that have "occupation (P106): tennis player (Q10833314)"
  	?player wdt:P569 ?date .       # with a P569 (date of birth) claim
	?player wdt:P21 wd:Q6581097 .       # with a P21 (sex or gender) "sex or gender (P21): male (Q6581097)" 
  	?player wdt:P536 ?atp_id .

  
 FILTER (?date < "1950-01-01T00:00:00Z"^^xsd:dateTime)
 FILTER isBLANK(?atp_id) .
	  
	OPTIONAL {?player rdfs:label ?player_label filter (lang(?player_label) = "en") .} 
	OPTIONAL {?cause rdfs:label ?cause_of_death_label filter (lang(?cause_of_death_label) = "en").}
}
ORDER BY ASC (?player)
}}
:Replace <code><nowiki>?player wdt:P536 ?atp_id .</nowiki></code> with <code><nowiki>filter not exists {?player wdt:P536 ?atp_id . }</nowiki></code> and delete <code><nowiki>FILTER isBLANK(?atp_id) .</nowiki></code> --[[User:Edgars2007|Edgars2007]] ([[User talk:Edgars2007|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 13:56, 25 February 2017 (UTC)

:: Thanks for the quick response. I now have this query but it gave me a timeout.--[[User:Wolbo|Wolbo]] ([[User talk:Wolbo|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 14:05, 25 February 2017 (UTC)

{{sparql|query=
#Male tennis players who were born before 1950 without an atp id
SELECT ?player ?date ?cause ?player_label
WHERE 
{
	?player wdt:P106 wd:Q10833314 .    # find items that have "occupation (P106): tennis player (Q10833314)"
  	?player wdt:P569 ?date .       # with a P569 (date of birth) claim
	?player wdt:P21 wd:Q6581097 .       # with a P21 (sex or gender) "sex or gender (P21): male (Q658109)"

 FILTER not exists {?player wdt:P536 ?atp_id . }
 FILTER (?date < "1950-01-01T00:00:00Z"^^xsd:dateTime)

	  
	OPTIONAL {?player rdfs:label ?player_label filter (lang(?player_label) = "en") .} 
	OPTIONAL {?cause rdfs:label ?cause_of_death_label filter (lang(?cause_of_death_label) = "en").}
}
ORDER BY ASC (?player)
LIMIT 100
}}
: Got it, the second OPTIONAL line was from a previous query and once deleted the query works. This stuff is interesting and fun!. --[[User:Wolbo|Wolbo]] ([[User talk:Wolbo|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 14:29, 25 February 2017 (UTC)
::{{ec}} Faster query: {{sparql|query=SELECT ?player ?playerLabel ?date {
  	?player wdt:P106 wd:Q10833314; wdt:P21 wd:Q6581097 .
  	FILTER not exists {?player wdt:P536 ?atp_id . }
  	#date things
  	?date_node wikibase:timeValue ?date .
  	FILTER (year(?date) < 1950)
  	?player p:P569/psv:P569 ?date_node .
  	SERVICE wikibase:label { bd:serviceParam wikibase:language "en,de,fr" . }
}
ORDER BY ASC (?player)
}}
::--[[User:Edgars2007|Edgars2007]] ([[User talk:Edgars2007|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 14:34, 25 February 2017 (UTC)
== Аward winners for Listeria ==

I already inserted Listeria tables in 2-3 articles about award winners, but I have two problems. First, I do not know how to add references? How are they extracted from SPARQL querry? And how to repeat author if he was a lauerat for two or more times?

Here is the example/problem I face [[:sr:НИН-ова награда]]. I would like to make a table with one row for each year, not for each author. And also, it would be nice to add references as the last column.

Here [[:sr:Дисова награда]], and here [[:sr:Жичка хрисовуља (награда)]] I have the same problem.
Could anyone help!? Thanks! --[[User:Милан Јелисавчић|Милан Јелисавчић]] ([[User talk:Милан Јелисавчић|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 19:36, 25 February 2017 (UTC)

== Select for Day of Birth ==

Supposing I want to look for women with en.wiki articles who died on 25 March in any year, to add to the [[w:en:March 25]] page ... what would be the query for that? My attempt below finds nothing, but removing FILTER(SUBSTR(STR(?dummydate),1,6) = 'Mar 25') . finds Mar 25 entries. Where (or how) am I going wrong? thanks --[[User:Tagishsimon|Tagishsimon]] ([[User talk:Tagishsimon|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 15:02, 26 February 2017 (UTC)

: {{SPARQL|query=
SELECT ?item ?dummydate WHERE {
	?item wdt:P21 wd:Q6581072 .
    ?item wdt:P570 ?dummydate

    FILTER(SUBSTR(STR(?dummydate),1,6) = 'Mar 25') .
 
    OPTIONAL {
    ?wiki0 <http://schema.org/about> ?item .
    FILTER(SUBSTR(STR(?wiki0),1,24) = 'https://en.wikipedia.org') .
    }
  FILTER(bound(?wiki0))
}
}}
::Not the right direction... See [[Wikidata talk:SPARQL query service/queries#Find people who were born in summer]]. --[[User:Edgars2007|Edgars2007]] ([[User talk:Edgars2007|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 15:05, 26 February 2017 (UTC)
:::Note, that you can replace all that "it has to have enwiki article" part with line from [[#Items with P106 but no Q5 in catalan wikipedia]]. --[[User:Edgars2007|Edgars2007]] ([[User talk:Edgars2007|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 15:07, 26 February 2017 (UTC)
::::Thanks Edgars2007, very much appreciated. Here's my homework - works a treat (this instance for 8 Aug). --[[User:Tagishsimon|Tagishsimon]] ([[User talk:Tagishsimon|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 19:28, 26 February 2017 (UTC)
: {{SPARQL|query=
SELECT ?item ?itemLabel ?date
	{
		{	SELECT ?item ?date
			{
				?date_node wikibase:timePrecision "11"^^xsd:integer . 
				?date_node wikibase:timeValue ?date . 
				FILTER (month(?date) = 8 && day(?date) = 8 ) 
				?item p:P569/psv:P569 ?date_node . 
			}
      
			LIMIT 1000
		}
		?item wdt:P31 wd:Q5 .
      	?item wdt:P21 wd:Q6581072 .
      SERVICE wikibase:label { bd:serviceParam wikibase:language "en" . }
      OPTIONAL {
    ?wiki0 <http://schema.org/about> ?item .
    FILTER(SUBSTR(STR(?wiki0),1,24) = 'https://en.wikipedia.org') .
    }
  FILTER(bound(?wiki0))
	}
}}
== Time zones and locations ==

{{P|421}} used to be applied mainly to countries. Currently this has been expanded to any type of locality.

It might be worth trying to build a series of queries that check {{P|421}} values by comparing them to P17 (countries should have the same P421), P131 and/or P625.

These could be either separate Listeria reports and/or complex constraints on [[Property talk:P421]]. <br/>--- [[User talk:Jura1|Jura]] 09:14, 26 February 2017 (UTC)

:Looks like there are too many statements to do this in across several countries in one query. To start:
:*[[Wikidata:Database reports/time zones/count]]
:*[[Wikidata:Database reports/time zones/by country]]
:<br/>--- [[User talk:Jura1|Jura]] 04:17, 28 February 2017 (UTC)

== Qualifier value not fetching ==

Can you please help why this query not returning value for some items.
: {{SPARQL|query=
SELECT ?item ?itemLabel ?desc ?state ?stateLabel ?eyear ?member ?memberLabel  WHERE {
  BIND(wd:Q1445 as ?state) # Tamil Nadu
  BIND (wd:Q3532431 as ?name)
  ?item wdt:P31 wd:Q3429959 . # constituency
  ?item wdt:P131 ?state . # get state name         
  #filter (?item = ?name) .
  ?item wdt:P585 ?eyear . # election year
filter (year(?eyear)=2014). # filter year of election
  optional{  ?item wdt:P991 ?member . }# member name from qualifier . Not fetching for some items.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
   OPTIONAL {
     ?item rdfs:label ?desc filter (lang(?desc) = "ta").
   }  
}
}}
Please help. Thanks -- [[User:Mdmahir|Mdmahir]] ([[User talk:Mdmahir|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 11:49, 28 February 2017 (UTC)

: I have fixed it myself. 
{{SPARQL|query=
SELECT ?item ?itemLabel ?desc ?state ?stateLabel ?eyear ?member ?memberLabel  WHERE {
  BIND(wd:Q1445 as ?state) # Tamil Nadu
  BIND (wd:Q3532431 as ?name)
  BIND (wd:Q3429959 as ?constituency)
  ?item wdt:P31/wdt:P279* ?constituency. # constituency
  ?item p:P131 ?statement . # get state name   
  ?item wdt:P131 ?state .
        
   ?item p:P585 [
     	ps:P585 ?eyear ;
        pq:P991 ?member;
   ].
     
  Filter (year(?eyear) = 2014) .
  #optional{?item wdt:P991 ?member  .}
 
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
   OPTIONAL {
     ?item rdfs:label ?desc filter (lang(?desc) = "ta").
   }  
}

}} . --[[User:Mdmahir|Mdmahir]] ([[User talk:Mdmahir|<span class="signature-talk">{{int:Talkpagelinktext}}</span>]]) 17:46, 28 February 2017 (UTC)